Did you know that the Arduino IDE can be used to program the micro:bit? Now you have yet another way to use this cool board! Learn how to set up Arduino to program your micro:bit, blink some LEDs, read the internal temperature sensor, send and receive data over Bluetooth - even log data to Adafruit.IO!

The micro:bit is a small nRF51-powered learning platform for kids - you can use it with Microsoft MakeCode (drag-n-drop block programming or Javascript), micropython, or mbed. But we really like using the Arduino IDE, especially since there's thousands of existing projects you can use and adapt. Also, you get to have much more advanced projects since you won't run out of memory (as you would with micropython) and you can write just about any code you want (with MakeCode you are more constrained to what has already been provided for you, a trade-off for ease-of-use).

Pick up a microbit and follow along on how you can do some pretty advanced things with your 'bit!

Install Windows 7 Driver

If you are running Windows 7 you need to install this driver.

If you are on Mac, Win 10+ or Linux it is not required! Skip this step

Download mBed serial driver

Download Arduino IDE

You will need to use the Desktop IDE. Make sure you are running the latest version.

Download Arduino IDE

Install SoftDevice onto MicroBit

Arduino assumes there's a 'softdevice' radio already installed. If you used MicroPython with your microbit, that softdevice was erased.

Reinstalling it is easy, download this hex and 'drag' it to your MICROBIT drive to install a MakeCode bluetooth advertising example. That, for sure, will force you to have a softdevice on :)

Download Microbit BTLE Advertising Demo

Add NRF5x Board Support

The microbit uses the nRF51 which is not 'natively' supported. But its easy to add support!

In Arduino, go to Preferences and add https://sandeepmistry.github.io/arduino-nRF5/package_nRF5_boards_index.json into the Additional Board Manager URL text box.

If this is not your first, make sure to separate URLs with a comma.

Open Tools>Board>Boards Manager from the menu bar, search for nRF5 and install "Nordic Semiconductor nRF5 Boards" by Sandeep Mistry

Select Board and Upload

Select BBC micro:bit from the Boards menu

Set SoftDevice to S110

And set the Port to the microbit

And create a new sketch with this blink demo

Download File

Copy Code

const int COL1 = 3;     // Column #1 control
const int LED = 26;     // 'row 1' led

void setup() {  
  Serial.begin(9600);
  
  Serial.println("microbit is ready!");

  // because the LEDs are multiplexed, we must ground the opposite side of the LED
  pinMode(COL1, OUTPUT);
  digitalWrite(COL1, LOW); 
   
  pinMode(LED, OUTPUT);   
}

void loop(){
  Serial.println("blink!");
  
  digitalWrite(LED, HIGH);
  delay(500);
  digitalWrite(LED, LOW);
  delay(500);
}

const int COL1 = 3;     // Column #1 control
const int LED = 26;     // 'row 1' led

void setup() {  
  Serial.begin(9600);
  
  Serial.println("microbit is ready!");

  // because the LEDs are multiplexed, we must ground the opposite side of the LED
  pinMode(COL1, OUTPUT);
  digitalWrite(COL1, LOW); 
   
  pinMode(LED, OUTPUT);   
}

void loop(){
  Serial.println("blink!");
  
  digitalWrite(LED, HIGH);
  delay(500);
  digitalWrite(LED, LOW);
  delay(500);
}

Click Upload!

If you get a warning about openocd - approve access so it can upload the code

You should see the top left LED blinking!

Linux Specific

The openocd build in the sandeepmistry package appears to be 32 bit. If you are running on a 64 bit linux install, you may get this error when trying to upload sketches:

{arduino folder}/packages/sandeepmistry/tools/openocd/0.10.0-dev.nrf5/bin/openocd: error while loading shared libraries: libudev.so.1: cannot open shared object file: No such file or directory

To get around this, install the 32 bit version of the libudev library with:

Download File

Copy Code

sudo apt-get install libudev1:i386

sudo apt-get install libudev1:i386

You may also run into a permissions issue when trying to upload the sketch to the micro:bit. If you get an error message that ends with lines like this:

Error: unable to open CMSIS-DAP device 0xd28:0x204
Error: No Valid JTAG Interface Configured.
Error: No Valid JTAG Interface Configured.

Then you'll need to add a udev rule. Place the contents below in a file named /etc/udev/rules.d/99-microbit.rules

Download File

Copy Code

ATTRS{idVendor}=="0d28", ATTRS{idProduct}=="0204", MODE="664", GROUP="plugdev"

ATTRS{idVendor}=="0d28", ATTRS{idProduct}=="0204", MODE="664", GROUP="plugdev"

And then plug the micro:bit back in for the settings to take effect.

Create a new sketch and upload the following code to read the button presses in the Serial Console

Download File

Copy Code

const int buttonA = 5;     // the number of the pushbutton pin
const int buttonB = 11;     // the number of the pushbutton pin

void setup() {  
  Serial.begin(9600);
  
  Serial.println("microbit is ready!");
  
  pinMode(buttonA, INPUT);  
  pinMode(buttonB, INPUT);   
}

void loop(){
  if (! digitalRead(buttonA)) {
    Serial.println("Button A pressed");
  }
  if (! digitalRead(buttonB)) {
    Serial.println("Button B pressed");
  }
  delay(10);
}

const int buttonA = 5;     // the number of the pushbutton pin
const int buttonB = 11;     // the number of the pushbutton pin

void setup() {  
  Serial.begin(9600);
  
  Serial.println("microbit is ready!");
  
  pinMode(buttonA, INPUT);  
  pinMode(buttonB, INPUT);   
}

void loop(){
  if (! digitalRead(buttonA)) {
    Serial.println("Button A pressed");
  }
  if (! digitalRead(buttonB)) {
    Serial.println("Button B pressed");
  }
  delay(10);
}

Open up the Serial console at 9600 baud and press the reset button on the back of the microbit to restart the software

You will see the welcome message and then try pressing some buttons!

You can easily get to GPIO #0 #1 and #2 using large alligator clips. With a microbit breakout, you can access the other 16 or so.

Note that many of these pins are multiplexed with the LED matrix so if you decide to use that, you can't use them for analog inputs or digital I/O

Pin #0 - large pad - analog in
Pin #1 - large pad - analog in
Pin #2 - large pad - analog in
Pin #3 - analog in, also used for LED matrix
Pin #4 - analog in, also used for LED matrix
Pin #5 - also used for Button A
Pin #6 - also used for LED matrix
Pin #7 - also used for LED matrix
Pin #8
Pin #9 - also used for LED matrix
Pin #10 - analog in, also used for LED matrix
Pin #11 - also used for button B
Pin #12
Pin #13 - also available as SPI clock
Pin #14 - also available as SPI MISO
Pin #15 - also available as SPI MOSI
Pin #16
Pin #19 - also available as I2C clock
Pin #20 - also available as I2C data

So really, if you're using the buttons and LEDs, you can use pins: #0, #1, #2, #8, #12, #13, #14, #15, #16, #19 and #20. Which is still a good amount!

blynk.cc has a great graphic of the pin mapping to Arduino IDE:

Check Board Version

The original version of the micro:bit has two separate sensors for the accelerometer and the magnetometer. Newer versions have a single sensor. To check which version you have, look on the board in the area shown below.

If you have two sensors then use the following libraries:

Magnetometer = MAG3110
Accelerometer = MMA8653

If you have a single sensor, then use the following library:

Magno/Accelo = LSM303AGR

Magnetometer (MAG3110)

Lets start with the magnetometer chip, the MAG3110

MAG3110 Datasheet

We can talk to the chip using an Arduino library

You can download Sparkfun's library by clicking the button below!

Download Sparkfun MAG3110 breakout library

And read our guide on how to install libraries

Restart the IDE. Now you can upload some examples. I suggest starting with the Basic example which is replicated below

Download File

Copy Code

/*  ********************************************* 
 *  SparkFun_MAG3110_Basic
 *  Triple Axis Magnetometer Breakout - MAG3110 
 *  Hook Up Guide Example 
 *  
 *  Utilizing Sparkfun's MAG3110 Library
 *  A basic sketch that reads x y and z readings
 *  from the MAG3110 sensor
 *  
 *  George B. on behalf of SparkFun Electronics
 *  Created: Sep 22, 2016
 *  Updated: n/a
 *  
 *  Development Environment Specifics:
 *  Arduino 1.6.7
 *  
 *  Hardware Specifications:
 *  SparkFun MAG3110
 *  Bi-directional Logic Level Converter
 *  Arduino Micro
 *  
 *  This code is beerware; if you see me (or any other SparkFun employee) at the
 *  local, and you've found our code helpful, please buy us a round!
 *  Distributed as-is; no warranty is given.
 *  *********************************************/

#include <SparkFun_MAG3110.h>

MAG3110 mag = MAG3110(); //Instantiate MAG3110

void setup() {
  Serial.begin(9600);

  mag.initialize(); //Initializes the mag sensor
  mag.start();      //Puts the sensor in active mode
}

void loop() {

  int x, y, z;
  //Only read data when it's ready
  if(mag.dataReady()) {
    //Read the data
    mag.readMag(&x, &y, &z);
  
    Serial.print("X: ");
    Serial.print(x);
    Serial.print(", Y: ");
    Serial.print(y);
    Serial.print(", Z: ");
    Serial.println(z);
  
    Serial.println("--------");
  }
}

/*  ********************************************* 
 *  SparkFun_MAG3110_Basic
 *  Triple Axis Magnetometer Breakout - MAG3110 
 *  Hook Up Guide Example 
 *  
 *  Utilizing Sparkfun's MAG3110 Library
 *  A basic sketch that reads x y and z readings
 *  from the MAG3110 sensor
 *  
 *  George B. on behalf of SparkFun Electronics
 *  Created: Sep 22, 2016
 *  Updated: n/a
 *  
 *  Development Environment Specifics:
 *  Arduino 1.6.7
 *  
 *  Hardware Specifications:
 *  SparkFun MAG3110
 *  Bi-directional Logic Level Converter
 *  Arduino Micro
 *  
 *  This code is beerware; if you see me (or any other SparkFun employee) at the
 *  local, and you've found our code helpful, please buy us a round!
 *  Distributed as-is; no warranty is given.
 *  *********************************************/

#include <SparkFun_MAG3110.h>

MAG3110 mag = MAG3110(); //Instantiate MAG3110

void setup() {
  Serial.begin(9600);

  mag.initialize(); //Initializes the mag sensor
  mag.start();      //Puts the sensor in active mode
}

void loop() {

  int x, y, z;
  //Only read data when it's ready
  if(mag.dataReady()) {
    //Read the data
    mag.readMag(&x, &y, &z);
  
    Serial.print("X: ");
    Serial.print(x);
    Serial.print(", Y: ");
    Serial.print(y);
    Serial.print(", Z: ");
    Serial.println(z);
  
    Serial.println("--------");
  }
}

Upload this to the microbit to see the following raw data:

Note that the magnetometer is not calibrated, so you'll get different numbers on XYZ but when you twist and rotate the mirobit the numbers should move up and down a bit! (This is why magnetometers must be calibrated)

Accelerometer (MMA8653)

The microbit has an onboard 3-axis accelerometer as well!

You can use this akafugu MMA8653 to communicate with it:

MMA8653.zip

Install like other libraries!

Next up, run this example code:

Download File

Copy Code

/*
 * MMA845XQ test code
 * (C) 2012 Akafugu Corporation
 *
 * This program is free software; you can redistribute it and/or modify it under the
 * terms of the GNU General Public License as published by the Free Software
 * Foundation; either version 2 of the License, or (at your option) any later
 * version.
 *
 * This program is distributed in the hope that it will be useful, but WITHOUT ANY
 * WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 * PARTICULAR PURPOSE.  See the GNU General Public License for more details.
 *
 */


#include "Wire.h"
#include "MMA8653.h"

MMA8653 accel;

void setup() {
  Serial.begin(9600);

  Serial.println("microbit accel test");
  
  accel.begin(false, 2); // 8-bit mode, 2g range
}


void loop() {
  accel.update();
  Serial.print(accel.getX());    Serial.print(" , ");
  Serial.print(accel.getY());    Serial.print(", ");
  Serial.println(accel.getZ());

  delay(100);
}

/*
 * MMA845XQ test code
 * (C) 2012 Akafugu Corporation
 *
 * This program is free software; you can redistribute it and/or modify it under the
 * terms of the GNU General Public License as published by the Free Software
 * Foundation; either version 2 of the License, or (at your option) any later
 * version.
 *
 * This program is distributed in the hope that it will be useful, but WITHOUT ANY
 * WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 * PARTICULAR PURPOSE.  See the GNU General Public License for more details.
 *
 */


#include "Wire.h"
#include "MMA8653.h"

MMA8653 accel;

void setup() {
  Serial.begin(9600);

  Serial.println("microbit accel test");
  
  accel.begin(false, 2); // 8-bit mode, 2g range
}


void loop() {
  accel.update();
  Serial.print(accel.getX());    Serial.print(" , ");
  Serial.print(accel.getY());    Serial.print(", ");
  Serial.println(accel.getZ());

  delay(100);
}

And open the serial monitor to see the X Y and Z acceleration data points!

This library is pretty old and incomplete so at this time you can only use it in 8-bit mode. If you want to get the data in g's use this for the loop:

Download File

Copy Code

void loop() {
  accel.update();
  Serial.print((float)accel.getX() * 0.0156);    Serial.print(" , ");
  Serial.print((float)accel.getY() * 0.0156);    Serial.print(", ");
  Serial.println((float)accel.getZ() * 0.0156);

  delay(100);
}

void loop() {
  accel.update();
  Serial.print((float)accel.getX() * 0.0156);    Serial.print(" , ");
  Serial.print((float)accel.getY() * 0.0156);    Serial.print(", ");
  Serial.println((float)accel.getZ() * 0.0156);

  delay(100);
}

Combined Accelerometer / Magnetometer (LSM303AGR)

Newer versions of the micro:bit have a single LSM303AGR sensor which has both an accelerometer and a magnetometer:

LSM303AGR

To use this version, you can use the LSM303AGR library from here:

LSM303AGR Library

You can install it via the Library Manager. Just search for LSM303AGR and pick the one from STM32duino:

The library comes with one example. Running it should give you the following output:

Once you want to get any more complex stuff going, you'll need a helper library to manage stuff like the internal temperature sensor, LED matrix, or Bluetooth connection.

To make your life easier, we've written up a wrapper library that manages all this stuff for you.

You'll also need to install some helpers.

Open up the Arduino library manager:

Search for the BLEPeripheral library and install it

Search for the Adafruit GFX library and install it

If using an earlier version of the Arduino IDE (prior to 1.8.10), also locate and install Adafruit_BusIO (newer versions will install this dependency automatically).

Search for the Adafruit Microbit library and install it

We also have a great tutorial on Arduino library installation at:
http://learn.adafruit.com/adafruit-all-about-arduino-libraries-install-use

Once you've re-started the Arduino IDE you should see the library examples appear in the File->Examples->Adafruit_Microbit menu

the LED matrix is a 25-LED multiplexed array. You can't just set the LED's on or off, they must be scanned through continuously to keep them lit. To make this easy for you we've added support to the Adafruit_Microbit library - it even uses a timer (Timer 2) to manage all the multiplexing for you.

First up, install the Adafruit helper libraries

Open up the matrixdemo sketch and upload it to your bit

The library manages all the refreshing, the drawing routines are all handled by Adafruit_GFX which we have documented in detail here https://learn.adafruit.com/adafruit-gfx-graphics-library/

Note that the screen is small so even though the GFX library can do a lot, there's not a ton of space for complex shapes. We do have a small and simple font you can use that will fit in the 5-pixel-tall display, called TomThumb.h

We've overloaded the print function so you can use that to print scrolling text:

Download File

Copy Code

// scroll some text the 'easy' way
microbit.print("HELLO WORLD");

// scroll some text the 'easy' way
microbit.print("HELLO WORLD");

or even numbers and floating points

Download File

Copy Code

// count up!
for (int i=0; i<10; i++) {
  microbit.print(i);
  delay(500);
}
microbit.print(3.1415, 4);  // pi time, 4 digits of precision!!

// count up!
for (int i=0; i<10; i++) {
  microbit.print(i);
  delay(500);
}
microbit.print(3.1415, 4);  // pi time, 4 digits of precision!!

Note that for single-digits or single-char print()'s you wont get scrolling text.

For bitmaps, the screen is 5x5 but to make the math easier on everyone, you can store bitmaps in 8-bit-wide structures and just ignore the left-most 3 bits in each 8-bit word:

Download File

Copy Code

const uint8_t
  smile_bmp[] =
  { B00000,
    B01010,
    B00000,
    B10001,
    B01110, };

const uint8_t
  smile_bmp[] =
  { B00000,
    B01010,
    B00000,
    B10001,
    B01110, };

We also have a range of built in images you can use here at the bottom.

You can draw bitmaps with show() - pass in either one of the built in microbit.BITMAP's or your own custom bitmap

Download File

Copy Code

// draw a heart
microbit.show(microbit.HEART);
delay(1000);

// draw a no cross
microbit.show(microbit.NO);
delay(1000);

// draw a yes check
microbit.show(microbit.YES);
delay(1000);

// draw a custom made bitmap face
microbit.show(smile_bmp);
delay(1000);

// draw a heart
microbit.show(microbit.HEART);
delay(1000);

// draw a no cross
microbit.show(microbit.NO);
delay(1000);

// draw a yes check
microbit.show(microbit.YES);
delay(1000);

// draw a custom made bitmap face
microbit.show(smile_bmp);
delay(1000);

The main chip has a bluetooth LE radio built in, which is how you can make cool wireless projects!

You can use the radio with our Adafruit Bluefruit Connect app without too much difficulty! You can download Bluefruit Connect in both the iOS App store and Android app stores

Learn more about our app over at the Connect guide, we'll assume you've read thru it so you have a rough idea how it works

Install Library & Example Code

First up, install the Adafruit helper library and friends

You can find our BLE demos in the examples menu:

Load up the BLE UART demo to start

Find these three lines:

Download File

Copy Code

  forward();
  //loopback();
  //spam();

  forward();
  //loopback();
  //spam();

and change them to:

Download File

Copy Code

//forward();
loopback();
spam();

//forward();
loopback();
spam();

This will turn on auto-transmitting data once a second which will make testing easier. Then upload the sketch

Bluetooth Connection

Once you have the sketch on the microbit, open up the Adafruit Bluefruit Connect app.

On the left there's a menu you can open. Select the microbit, it might be named UART or Arduino

Press Connect

Then select UART from the list of Modules. Go into Timestamp mode and you should see messages once a second:

Go back to the sketch and change it back to:

Download File

Copy Code

  forward();
  //loopback();
  //spam();

  forward();
  //loopback();
  //spam();

Re-upload. The app will complain you disconnected, just go back and disconnect from the peripheral-list menu.

Open the serial console at 115200 baud

Then when you go back to UART mode, you can send data from the tablet to the bit and back. Note that the microbit's UART is a little odd - don't send more than 10 or so characters 'at a time' through the serial monitor or it may hang.

Once you've got all that working, you can try our controller sketch!

The Bluefruit App has a built in plotter that will let you easily visualize data from your microbit! Be sure you got the UART examples working from earlier.

Install Library & Example Code

First up, install the Adafruit helper library and friends

You can find our BLE demos in the examples menu:

Load up the BLE Plotter demo

This time, in the App, select the Plotter module. You will be able to see the X, Y and Z data appear and scroll down!

You can plot anything you like, just use bleSerial.print() and print out your data with commas in between. At the end of a data set have a bleSerial.println() and it will plot each comma-separated-element as a unique graph

So if you want to just graph the total acceleration vector sqrt(x^2 + y^2 + z^2), use this code snippet:

Download File

Copy Code

void loop() {
  bleSerial.poll();

  accel.update();

  // print the data on serial port
  Serial.print(accel.getX());    Serial.print(", ");
  Serial.print(accel.getY());    Serial.print(", ");
  Serial.println(accel.getZ());

  float vector = (accel.getX() * accel.getX()) + (accel.getY() * accel.getY()) +  (accel.getZ() * accel.getZ());
  vector = sqrt(vector);

  // send it over bluetooth
  bleSerial.println(vector);

  delay(100);
}

void loop() {
  bleSerial.poll();

  accel.update();

  // print the data on serial port
  Serial.print(accel.getX());    Serial.print(", ");
  Serial.print(accel.getY());    Serial.print(", ");
  Serial.println(accel.getZ());

  float vector = (accel.getX() * accel.getX()) + (accel.getY() * accel.getY()) +  (accel.getZ() * accel.getZ());
  vector = sqrt(vector);

  // send it over bluetooth
  bleSerial.println(vector);

  delay(100);
}

For controlling projects, you may want to use our Controller module. It has a bunch of useful interface features that will let you make your next LED or robotics project super easy

Install Library & Example Code

Install the Adafruit helper library and friends

Open up the BLE Controller demo

Load that into your microbit, and connect using BLE connect

The top 5 selectors allow you to stream data from your tablet or phone to the 'bit. So for example you can send tablet orientation (Quaternion) or GPS location to the 'bit. Turn on one, all five or none.

The two bottom modules can be run whenever you like, click to open up the interfaces:

The color picker will let you choose from a color wheel and send the 24-bit color over BLE to the microbit

The control pad interface gives you 8 buttons that you can press - each press and release will send a signal to the microbit.

If the microbit sends any data back to the device, it will appear in the text bar above.

You can look at the serial monitor to see the messages as they are received.

All this Bluetooth data stuff is good if you want to plot the data or add control from your phone. But what if you want to store the data long term, or add remote control from around the world?

It's not too hard! We can use Adafruit IO to create graphs and dashboards. And, best of all, its free just like the Bluefruit app!

Before continuing, set yourself up with an Adafruit IO account

We won't cover all the details of Adafruit IO here, so check out the guides we have already written for that good stuff!

Create a Microbit Temperature Feed

We'll want a 'place' for our temperature, so create a new feed called temp

Temperature Logger Sketch

Install the Adafruit helper library and friends

Open up the BLE die temp demo

This will read the temperature on the chip itself. It's not precise at all but it does go up when it gets hotter and down when it gets cooler, so its a good place to start and you don't need any additional hardware

Note that this sketch takes 50 readings and averages it, then waits 5000 ms (5 seconds) between data reports. That's because Adafruit IO is limited in how much data you can upload and store, so we will take it a little slowly.

Upload the sketch and open the serial monitor so you can verify the temperature data there:

Test UART Mode

Connect to the microbit over your device using Adafruit Bluefruit Connect as covered in the previous projects, and select UART mode. You should see data slowly coming in

You can also plot the data. Note that the data is really not very precise or accurate. But if you heat up the nRF51 with a lamp, the temperature will slowly rise up:

Now go back to UART mode and click the MQTT button in the top right:

Note that the MQTT server and port will be prefilled for Adafruit IO.

Skip down and enter in your Adafruit IO Username and API Key (even though it says Password, use the long alphanumeric API key)

Then take that and put it here like so:

Finally enter in the feed name which is username/f/tempbit into the UART RX Publish entry. (There's currently a bug where you have to have something in the Subscribe so we put the same feed in there):

Then click Connect at the top:

Wait a few minutes and go visit your Adafruit IO Feeds page, you should see the data start to stream in!

Huzzah! You can now create a public dashboard if you like, to share it with others

If you're having issues, you may want to check Sandeep's installation guide for the nRF5x package which may have more details (in case there are updates)

Some people reported that their microbit did not have a softdevice on it already (which seems odd but is possible!) You can try installing this hex file which will use MakeCode to install a softdevice. Just drag it onto the MICROBIT disk drive

microbit-adv.hex

There's also instructions here on how to manually install a softdevice or in the off chance you want softdevice 130 instead of the 'standard' s110 (see Flashing SoftDevice)

This guide was first published on Sep 27, 2017. It was last updated on Sep 29, 2017.