Overview

The sino:bit a single-board microcontroller designed for computer education in China. It is based on the Calliope miniwith permission of the Calliope mini project. While several modifications are planned, the first was to upgrade the LED matrix from 5×5 to 12×12. This allows for support of Chinese, Japanese, Hindi, Arabic and other non-Latin character based languages. Without this, the vast majority of the World’s children cannot experience the thrill of that first “Hello World” in their own language.

The sino:bit was created by Naomi Wu, an Open Source Hardware evangelist and DIY enthusiast. It was executed and engineered by Elecrow Technology, a Shenzhen based electronics company that offers contract manufacturing and engineering services to Maker and Hardware Enthusiasts.

Did you know that the Arduino IDE can be used to program the Sino:bit? Now you have yet another way to use this cool board! Learn how to set up Arduino to program your sino:bit, blink some LEDs, read the internal temperature sensor, send and receive data over Bluetooth - even log data to Adafruit.IO!

The Sino:bit is a derivation of the Calliope Mini, which is a derivative of the BBC Micro:bit. It is based on the same nRF51822 MCU from Nordic. It includes the same accelerometer and magnetometer. It provides 2 user readable buttons. It has a matrix of LEDs for displaying whatever you want. There is a micro USB connector for programming it, and a JST 3v battery connector for when you don't want to be tied to a desktop or laptop. Finally, there is the ability to add a standard 2x13 0.1" spacing header for adding hardware in a robust way.

There are some differences as well, some of which I believe are significant improvements.

The Sino:bit has pads/holes for alligator clips, but there are 8 . After power and ground, this leaves you with 6 pads for I/O. Also, they are at the 8 corners of the octagonal board, off by themselves so you aren't likely to accidentally short with other signals.

Finally, and this is HUGE, the Sino:bit has a 12x12 LED matrix in place of a 5x5 matrix. While this has many advantages (see a later page) the primary motivation is to be able to display non-roman alphabets, specifically Chinese.

Pick up a Sino:bit and follow along on how you can do some pretty advanced things with it!

Another thing that makes the Sino:bit special is that has the distinction of being the very first OSHWA certified open source hardware in China.

Install board and blink!

Install Windows 7 Driver

If you are running Windows 7 you need to install this driver.

If you are on Mac, Win 10+ or Linux it is not require! Skip this step

Download Arduino IDE

You will need to use the Desktop IDE. Make sure you are running the latest version.

Install SoftDevice onto SinoBit

Arduino assumes there's a 'softdevice' radio already installed. If you used MicroPython with your sinobit, that softdevice was erased.

Reinstalling it is easy, simply follow the instructions at Sandeep Mistry's instructions. When selecting the programmer, I had success using CMSIS-DAP. I made a point of resetting it to USPTinyISP when the SoftDevice flashing was complete.

Add NRF5x Board Support

The microbit uses the nRF51 which is not 'natively' supported. But its easy to add support!

In Arduino, go to Preferences and add https://sandeepmistry.github.io/arduino-nRF5/package_nRF5_boards_index.json into the Additional Board Manager URL text box.

 

If this is not your first, make sure to separate URLs with a comma.

Open Tools>Board>Boards Manager from the menu bar, search for nRF5 and install "Nordic Semiconductor nRF5 Boards" by Sandeep Mistry

Install the Sino:bit library.

Currently, Sino:bit support is in a separate library but should eventually be included with the nRF5 board support.  For now, we can treat the Sino:bit as a Micro:bit with a bit extra.  The Sino:bit library provides that extra.

The experimental version of the library is at https://github.com/dastels/Sinobit and you can download and install it manually. Just click this button to download the zip:

Rename the uncompressed folder Sinobit and check that the Sinobit folder contains src and example folders.

Place the Sinobit library folder your arduinosketchfolder/libraries/ folder. 
You may need to create the libraries subfolder if its your first library. Restart the IDE.

Select Board and Upload

Select BBC micro:bit from the Boards menu.

Set SoftDevice to S110.

And set the Port to the microbit

And create a new sketch with this blink demo.

#include <sinobit.h>

Sinobit matrix = Sinobit();

void setup() {
  Serial.begin(9600);
  Serial.println("Sinobit is ready!");

  matrix.begin();
  delay(100);
  matrix.clearScreen();
}

void loop() {
  Serial.println("blink!");
  
  // set a pixel
  matrix.drawPixel(0, 0, 1);
  matrix.writeScreen();
  delay(500);
  
  // clear a pixel!
  matrix.drawPixel(0, 0, 0);
  matrix.writeScreen();
  delay(500);
}

Click Upload!

If you get a warning about openocd - approve access so it can upload the code

You should see the top left LED blinking!

Buttons

Create a new sketch and upload the following code to read the button presses in the Serial Console

Open up the Serial console at 9600 baud and press the reset button on the back of the microbit to restart the software

You will see the welcome message and then try pressing some buttons!

Take note: Button A is to the right of the LEDs on the Sino:bit, while button B is to the left.

    const int buttonA = 5;     // the number of the pushbutton pin
const int buttonB = 11;     // the number of the pushbutton pin

void setup() {  
  Serial.begin(9600);
  Serial.println("microbit is ready!");
  
  pinMode(buttonA, INPUT);  
  pinMode(buttonB, INPUT);   
}

void loop(){
  if (! digitalRead(buttonA)) {
    Serial.println("Button A pressed");
  }
  if (! digitalRead(buttonB)) {
    Serial.println("Button B pressed");
  }
  delay(10);
}
  

If you include sinobit.h, you can use constants it defines for the buttons:

#include <sinobit.h>

void setup() {  
  Serial.begin(9600);
  Serial.println("microbit is ready!");
  
  pinMode(SINOBIT_BUTTON_A, INPUT);  
  pinMode(SINOBIT_BUTTON_B, INPUT);   
}

void loop(){
  if (! digitalRead(SINOBIT_BUTTON_A)) {
    Serial.println("Button A pressed");
  }
  if (! digitalRead(SINOBIT_BUTTON_B)) {
    Serial.println("Button B pressed");
  }
  delay(10);
}

NOTE:

The button signals are what we call "active low" meaning that the button input is low (i.e. false) when the button is pressed and high (i.e. true) when it isn't.

Other GPIO

There are a few different I/O options on the Sino:bit. Let's look at each in turn.

Alligator Clip Pads

 Around the edge of the board are 8 pads for attaching alligator clips. In addition to 3v (VCC) and ground (GND) are 6 I/O connections labelled P0-P5. This is twice as many clip pads as the Micro:Bit. Like the Calliope, they are well removed from any other connections which reduces the risk of shorting with other signals.  The library provides constants for referencing these pads.

The example below will pulse each of the pads in turn, repeatedly.

#include <sinobit.h>

void setup() {
  pinMode(SINOBIT_PAD_P0, OUTPUT);
  pinMode(SINOBIT_PAD_P1, OUTPUT);
  pinMode(SINOBIT_PAD_P2, OUTPUT);
  pinMode(SINOBIT_PAD_P3, OUTPUT);
  pinMode(SINOBIT_PAD_P4, OUTPUT);
  pinMode(SINOBIT_PAD_P5, OUTPUT);
}

void pulse(int io_pin)
{
  digitalWrite(io_pin, HIGH);
  delay(100);
  digitalWrite(io_pin, LOW);
  delay(100);
}

void loop() {
  pulse(SINOBIT_PAD_P0);
  pulse(SINOBIT_PAD_P1);
  pulse(SINOBIT_PAD_P2);
  pulse(SINOBIT_PAD_P3);
  pulse(SINOBIT_PAD_P4);
  pulse(SINOBIT_PAD_P5);
}

UART

At the top left of the board is a four pin connector with GND, 5v, Rx, and Tx.  Rx is also Pad P1 and P1 on the I/O connector (see below). Similarly Tx is Pad P2 and P2 on the expansion connector. This provides great flexibility in how you can connect to the UART: alligator clip wires, a 4-pin cable, or an expansion board.

I2C

Similarly to the UART, I2C signals are available on a four-pin connector at the top right of the board. Also like the UART signals, SDA and SCL are available on the expansion connector: SCL on P19, and SDA on P20. Unlike the UART signals, they are not available on any clip pads.

Expansion Connector

This is your standard 2x13 0.1" spacing connector. You can put a male header here facing up (so wires connect on the LED side of the board) for easy connection to a breadboard for prototyping, or a female header on the back for mounting an expansion board so that it doesn't block the LEDs. You could use a male header there as well, but I would use female to avoid the possibility of shorting against metallic stuff that might be on your desk or workbench. Then again that could get you a Sparky the Magic Blue Smoke Monster pin.

All the available I/O signals are on this connector: digital & analog connections, I2C, UART, and SPI. Additionally there are ground, 3.3v, and 5v lines.

As with the clip pads, the library defines constants for referring to these signals.

You have these connections available as you do on the Micro:bit. A big difference (described later) is that the LED matrix doesn't impact your use of I/O. Also, there are more available via clip pads.

  • Pin #0 - clip pad - analog in
  • Pin #1 - clip pad - analog in, also used for Rx
  • Pin #2 - clip pad - analog in, also used for Tx
  • Pin #3 - clip pad, analog in
  • Pin #4 - clip pad, analog in
  • Pin #5 - also used for Button A
  • Pin #6
  • Pin #7
  • Pin #8
  • Pin #9
  • Pin #10 - clip pad, analog in
  • Pin #11 - also used for button B
  • Pin #12
  • Pin #13 - also available as SPI clock
  • Pin #14 - also available as SPI MISO
  • Pin #15 - also available as SPI MOSI
  • Pin #16
  • Pin #19 - also available as I2C clock
  • Pin #20 - also available as I2C data

There's still a bit of confusion over some of the details on this connector. Keep in mind that this v1 of the board and these details should be ironed out in coming versions.

Accelerometer and Magnetometer

Magnetometer

Lets start with the magnetometer chip, the MAG3110

We can talk to the chip using an Arduino library

You can download Sparkfun's library by clicking the button below!

And read our guide on how to install libraries

Restart the IDE. Now you can upload some examples. I suggest starting with the Basic example which is replicated below

/*  ********************************************* 
 *  SparkFun_MAG3110_Basic
 *  Triple Axis Magnetometer Breakout - MAG3110 
 *  Hook Up Guide Example 
 *  
 *  Utilizing Sparkfun's MAG3110 Library
 *  A basic sketch that reads x y and z readings
 *  from the MAG3110 sensor
 *  
 *  George B. on behalf of SparkFun Electronics
 *  Created: Sep 22, 2016
 *  Updated: n/a
 *  
 *  Development Environment Specifics:
 *  Arduino 1.6.7
 *  
 *  Hardware Specifications:
 *  SparkFun MAG3110
 *  Bi-directional Logic Level Converter
 *  Arduino Micro
 *  
 *  This code is beerware; if you see me (or any other SparkFun employee) at the
 *  local, and you've found our code helpful, please buy us a round!
 *  Distributed as-is; no warranty is given.
 *  *********************************************/

#include <SparkFun_MAG3110.h>

MAG3110 mag = MAG3110(); //Instantiate MAG3110

void setup() {
  Serial.begin(9600);

  mag.initialize(); //Initializes the mag sensor
  mag.start();      //Puts the sensor in active mode
}

void loop() {

  int x, y, z;
  //Only read data when it's ready
  if(mag.dataReady()) {
    //Read the data
    mag.readMag(&x, &y, &z);
  
    Serial.print("X: ");
    Serial.print(x);
    Serial.print(", Y: ");
    Serial.print(y);
    Serial.print(", Z: ");
    Serial.println(z);
  
    Serial.println("--------");
  }
}

Upload this to the microbit to see the following raw data:

Note that the magnetometer is not calibrated, so you'll get different numbers on XYZ but when you twist and rotate the mirobit the numbers should move up and down a bit! (This is why magnetometers must be calibrated)

Accelerometer

The microbit has an onboard 3-axis accelerometer as well!

You can use this akafugu MMA8653 to communicate with it:

Install like other libraries!

Next up, run this example code:

/*
 * MMA845XQ test code
 * (C) 2012 Akafugu Corporation
 *
 * This program is free software; you can redistribute it and/or modify it under the
 * terms of the GNU General Public License as published by the Free Software
 * Foundation; either version 2 of the License, or (at your option) any later
 * version.
 *
 * This program is distributed in the hope that it will be useful, but WITHOUT ANY
 * WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 * PARTICULAR PURPOSE.  See the GNU General Public License for more details.
 *
 */


#include "Wire.h"
#include "MMA8653.h"

MMA8653 accel;

void setup() {
  Serial.begin(9600);

  Serial.println("microbit accel test");
  
  accel.begin(false, 2); // 8-bit mode, 2g range
}


void loop() {
  accel.update();
  Serial.print(accel.getX());    Serial.print(" , ");
  Serial.print(accel.getY());    Serial.print(", ");
  Serial.println(accel.getZ());

  delay(100);
}

And open the serial monitor to see the X Y and Z acceleration data points!

This library is pretty old and incomplete so at this time you can only use it in 8-bit mode. If you want to get the data in g's use this for the loop:

void loop() {
  accel.update();
  Serial.print((float)accel.getX() * 0.0156);    Serial.print(" , ");
  Serial.print((float)accel.getY() * 0.0156);    Serial.print(", ");
  Serial.println((float)accel.getZ() * 0.0156);

  delay(100);
}

Adafruit Libraries

Once you want to get any more complex stuff going, you'll need a helper library to manage stuff like the internal temperature sensor, LED matrix, or Bluetooth connection.

To make your life easier, we've written up a wrapper library that manages all this stuff for you.

You'll also need to install some helpers:

Download BLE Peripheral library

In the Arduino library manager, install the BLE Peripheral library:

Download Adafruit GFX library

In the Arduino library manager, install the Adafruit GFX library:

Download Adafruit_Microbit library

To use the LED matrix or Bluetooth connection, you will need to download Adafruit_Microbit from our github repository. You can do that by visiting the github repo and manually downloading or, easier, just click this button to download the zip:

Rename the uncompressed folder Adafruit_Microbit and check that the Adafruit_Microbit folder contains Adafruit_Microbit.cpp and Adafruit_Microbit.h

Place the Adafruit_Microbit library folder your arduinosketchfolder/libraries/ folder. 
You may need to create the libraries subfolder if its your first library. Restart the IDE.

We also have a great tutorial on Arduino library installation at:
http://learn.adafruit.com/adafruit-all-about-arduino-libraries-install-use

Once you've re-started the Arduino IDE you should see the library examples appear in the File->Examples->Adafruit_Microbit menu

LED Matrix

The LED matrix on the Sino:bit has several important differences from the one found on the Micro:bit.

The most obvious is that it is a 12x12 matrix rather than a 5x5 one. That's 144 LEDs instead of 25. The primary reason for this is to support non-roman alphabets, for which 5x5 is far to small. Even if you don't need that capability, the larger display space is incredibly useful. The Sino:bit library works in conjunction with the GFX library to provide graphics primitives that can be used to good effect on the larger matrix. To demonstrate this, one of the examples with the library is an implementation of Conway's Game of Life, based on the code at https://learn.adafruit.com/mini-commodore-pet-with-charlieplexed-led-matrix/software.

The LED matrix is not managed by the MCU as it is on the Micro:bit; it would take to much of the MCU's time. The designers of the Sino:bit used the Holtek HT1632 to manage the LEDs. All the MCU has to do is tell the HT1632 the state of each LED. As a result there is more computing power available to use for our code.

The Sino:bit library handles all that for you, letting you work with it via the GFX primitives. Here's a slightly different button example that uses the LEDs to indicate button state.

#include <sinobit.h>

Sinobit matrix = Sinobit();

void setup() {
  matrix.begin();
  delay(100);
  matrix.clearScreen();
  matrix.setTextWrap(false);

  pinMode(SINOBIT_BUTTON_A, INPUT);
  pinMode(SINOBIT_BUTTON_B, INPUT);
}

void loop() {
  if (!digitalRead(SINOBIT_BUTTON_A)) {
    matrix.drawLine(7, 1, 11, 5, 1);
    matrix.drawLine(7, 10, 11, 6, 1);
  } else {
    matrix.drawLine(7, 1, 11, 5, 0);
    matrix.drawLine(7, 10, 11, 6, 0);
  }

  if (!digitalRead(SINOBIT_BUTTON_B)) {
    matrix.drawLine(4, 1, 0, 5, 1);
    matrix.drawLine(4, 10, 0, 6, 1);
  } else {
    matrix.drawLine(4, 1, 0, 5, 0);
    matrix.drawLine(4, 10, 0, 6, 0);  
  }

  matrix.writeScreen();
}

Analog Input

Since the Sino:bit uses the same MCU as the Micro:bit, it has the same analog input capabilities (see the GPIO section).

int analogPin = 0;
int val = 0;

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  delay(1000);
  val = analogRead(analogPin);
  Serial.println(val);
}

The big LED matrix gives us more potential for displaying things, like a histogram of analog readings.

#include <sinobit.h>

Sinobit matrix = Sinobit();

int analogPin = SINOBIT_PAD_P0;
int readings[12];

void setup()
{
  matrix.begin();
  delay(100);
  matrix.clearScreen();
  for (int i = 0; i < 12; i++) {
    readings[i] = 0;
  }
}

void loop()
{
  delay(1000);

  for (int i = 0; i < 11; i++) {
    readings[i] = readings[i + 1];
  }
  // experience showed that my photocell never got to a max reading
  // which is why I use 12 as the upper limit instead of 11 as expected
  readings[11] = map(analogRead(analogPin), 0, 1023, 0, 12);

  for (int i = 0; i < 12; i++) {
    if (readings[i] == 0) {
      matrix.drawLine(i, 11, i, 0, 0);
    } else if (readings[i] == 11) {
      matrix.drawLine(i, 11, i, 0, 1);
    } else {
      matrix.drawLine(i, 11, i, 12 - readings[i], 1);
      matrix.drawLine(i, 11 - readings[i], i, 0, 0);
    }
  }

  matrix.writeScreen();
}

Bluetooth

Since the Sino:bit uses the same MCU as the Micro:bit, it has the same bluetooth functionality. This allows you to communicate with other boards (Sino:bits, Micro:bits, Calliopes) or your smartphone/tablet.  These examples use the Adafruit Bluefruit app.

Bluetooth UART

The main chip has a bluetooth LE radio built in, which is how you can make cool wireless projects!

You can use the radio with our Adafruit Bluefruit Connect app without too much difficulty! You can download Bluefruit Connect in both the iOS App store and Android app stores

Learn more about our app over at the Connect guide, we'll assume you've read thru it so you have a rough idea how it works

Install Library & Example Code

First up, install the Adafruit helper library and friends

You can find our BLE demos in the examples menu:

Load up the BLE UART demo to start

Find these three lines:

  forward();
  //loopback();
  //spam();

and change them to:

//forward();
loopback();
spam();

This will turn on auto-transmitting data once a second which will make testing easier. Then upload the sketch

Bluetooth Connection

Once you have the sketch on the microbit, open up the Adafruit Bluefruit Connect app.

On the left there's a menu you can open. Select the microbit, it might be named UART or Arduino

Press Connect

Then select UART from the list of Modules. Go into Timestamp mode and you should see messages once a second:

Go back to the sketch and change it back to:

  forward();
  //loopback();
  //spam();

Re-upload. The app will complain you disconnected, just go back and disconnect from the peripheral-list menu.

Open the serial console at 115200 baud

Then when you go back to UART mode, you can send data from the tablet to the bit and back. Note that the microbit's UART is a little odd - don't send more than 10 or so characters 'at a time' through the serial monitor or it may hang.

Once you've got all that working, you can try our controller sketch!

Bluetooth Plotter

The Bluefruit App has a built in plotter that will let you easily visualize data from your microbit! Be sure you got the UART examples working from earlier.

Install Library & Example Code

First up, install the Adafruit helper library and friends

You can find our BLE demos in the examples menu:

Load up the BLE Plotter demo

This time, in the App, select the Plotter module. You will be able to see the X, Y and Z data appear and scroll down!

You can plot anything you like, just use bleSerial.print() and print out your data with commas in between. At the end of a data set have a bleSerial.println() and it will plot each comma-separated-element as a unique graph

So if you want to just graph the total acceleration vector sqrt(x^2 + y^2 + z^2), use this code snippet:

void loop() {
  bleSerial.poll();

  accel.update();

  // print the data on serial port
  Serial.print(accel.getX());    Serial.print(", ");
  Serial.print(accel.getY());    Serial.print(", ");
  Serial.println(accel.getZ());

  float vector = (accel.getX() * accel.getX()) + (accel.getY() * accel.getY()) +  (accel.getZ() * accel.getZ());
  vector = sqrt(vector);

  // send it over bluetooth
  bleSerial.println(vector);

  delay(100);
}

Bluetooth Controller

For controlling projects, you may want to use our Controller module. It has a bunch of useful interface features that will let you make your next LED or robotics project super easy

Install Library & Example Code

Install the Adafruit helper library and friends

Open up the BLE Controller demo

Load that into your microbit, and connect using BLE connect

The top 5 selectors allow you to stream data from your tablet or phone to the 'bit. So for example you can send tablet orientation (Quaternion) or GPS location to the 'bit. Turn on one, all five or none.

The two bottom modules can be run whenever you like, click to open up the interfaces:

The color picker will let you choose from a color wheel and send the 24-bit color over BLE to the microbit

The control pad interface gives you 8 buttons that you can press - each press and release will send a signal to the microbit.

If the microbit sends any data back to the device,  it will appear in the text bar above.

You can look at the serial monitor to see the messages as they are received.

Logging Temperature to Adafruit IO

All this Bluetooth data stuff is good if you want to plot the data or add control from your phone. But what if you want to store the data long term, or add remote control from around the world?

It's not too hard! We can use Adafruit IO to create graphs and dashboards. And, best of all, its free just like the Bluefruit app!

You can read more about Adafruit IO in this guide

Before continuing, set yourself up with an Adafruit IO account

We won't cover all the details of Adafruit IO here, so check out the guides we have already written for that good stuff!

Create a Microbit Temperature Feed

We'll want a 'place' for our temperature, so create a new feed called temp

Temperature Logger Sketch

Install the Adafruit helper library and friends

Open up the BLE die temp demo

This will read the temperature on the chip itself. It's not precise at all but it does go up when it gets hotter and down when it gets cooler, so its a good place to start and you don't need any additional hardware

Note that this sketch takes 50 readings and averages it, then waits 5000 ms (5 seconds) between data reports. That's because Adafruit IO is limited in how much data you can upload and store, so we will take it a little slowly.

Upload the sketch and open the serial monitor so you can verify the temperature data there:

Test UART Mode

Connect to the microbit over your device using Adafruit Bluefruit Connect as covered in the previous projects, and select UART mode. You should see data slowly coming in

You can also plot the data. Note that the data is really not very precise or accurate. But if you heat up the nRF51 with a lamp, the temperature will slowly rise up:

Now go back to UART mode and click the MQTT button in the top right:

Note that the MQTT server and port will be prefilled for Adafruit IO.

Skip down and enter in your Adafruit IO Username and API Key (even though it says Password, use the long alphanumeric API key)

Then take that and put it here like so:

Finally enter in the feed name which is username/f/tempbit into the UART RX Publish entry. (There's currently a bug where you have to have something in the Subscribe so we put the same feed in there):

Then click Connect at the top:

Wait a few minutes and go visit your Adafruit IO Feeds page, you should see the data start to stream in!

HALP!!!

If you're having issues, you may want to check Sandeep's installation guide for the nRF5x package which may have more details (in case there are updates)

Some people reported that their microbit did not have a softdevice on it already (which seems odd but is possible!) You can try installing this hex file which will use MakeCode to install a softdevice. Just drag it onto the MICROBIT disk drive