Using the NAU7802 with Arduino involves wiring up the sensor to your Arduino-compatible microcontroller, installing the Adafruit_NAU7802 library and running the provided example code.
Wiring
Wire as shown for a 5V board like an Uno. If you are using a 3V board, like an Adafruit Feather, wire the board's 3V pin to the NAU7802 VIN.
Here is an Adafruit Metro wired up to the NAU7802 using the STEMMA QT connector:
-
Board 5V to ADC VIN (red wire)
-
Board GND to ADC GND (black wire)
-
Board SCL to ADC SCL (yellow wire)
- Board SDA to ADC SDA (blue wire)
Here is an Adafruit Metro wired up using a solderless breadboard:
-
Board 5V to ADC VIN (red wire)
-
Board GND to ADC GND (black wire)
-
Board SCL to ADC SCL (yellow wire)
- Board SDA to ADC SDA (blue wire)
Library Installation
You can install the NAU7802 library for Arduino using the Library Manager in the Arduino IDE.
Click the Manage Libraries ... menu item, search for NAU7802, and select the Adafruit NAU7802 Library library:
If asked about dependencies, click "Install all".
If the "Dependencies" window does not come up, then you already have the dependencies installed.
Load Example
Open up File -> Examples -> Adafruit NAU7802 Library -> nau7802_test and upload to your Arduino wired to the sensor.
#include <Adafruit_NAU7802.h>
Adafruit_NAU7802 nau;
void setup() {
Serial.begin(115200);
Serial.println("NAU7802");
if (! nau.begin()) {
Serial.println("Failed to find NAU7802");
while (1) delay(10); // Don't proceed.
}
Serial.println("Found NAU7802");
nau.setLDO(NAU7802_3V0);
Serial.print("LDO voltage set to ");
switch (nau.getLDO()) {
case NAU7802_4V5: Serial.println("4.5V"); break;
case NAU7802_4V2: Serial.println("4.2V"); break;
case NAU7802_3V9: Serial.println("3.9V"); break;
case NAU7802_3V6: Serial.println("3.6V"); break;
case NAU7802_3V3: Serial.println("3.3V"); break;
case NAU7802_3V0: Serial.println("3.0V"); break;
case NAU7802_2V7: Serial.println("2.7V"); break;
case NAU7802_2V4: Serial.println("2.4V"); break;
case NAU7802_EXTERNAL: Serial.println("External"); break;
}
nau.setGain(NAU7802_GAIN_128);
Serial.print("Gain set to ");
switch (nau.getGain()) {
case NAU7802_GAIN_1: Serial.println("1x"); break;
case NAU7802_GAIN_2: Serial.println("2x"); break;
case NAU7802_GAIN_4: Serial.println("4x"); break;
case NAU7802_GAIN_8: Serial.println("8x"); break;
case NAU7802_GAIN_16: Serial.println("16x"); break;
case NAU7802_GAIN_32: Serial.println("32x"); break;
case NAU7802_GAIN_64: Serial.println("64x"); break;
case NAU7802_GAIN_128: Serial.println("128x"); break;
}
nau.setRate(NAU7802_RATE_10SPS);
Serial.print("Conversion rate set to ");
switch (nau.getRate()) {
case NAU7802_RATE_10SPS: Serial.println("10 SPS"); break;
case NAU7802_RATE_20SPS: Serial.println("20 SPS"); break;
case NAU7802_RATE_40SPS: Serial.println("40 SPS"); break;
case NAU7802_RATE_80SPS: Serial.println("80 SPS"); break;
case NAU7802_RATE_320SPS: Serial.println("320 SPS"); break;
}
// Take 10 readings to flush out readings
for (uint8_t i=0; i<10; i++) {
while (! nau.available()) delay(1);
nau.read();
}
while (! nau.calibrate(NAU7802_CALMOD_INTERNAL)) {
Serial.println("Failed to calibrate internal offset, retrying!");
delay(1000);
}
Serial.println("Calibrated internal offset");
while (! nau.calibrate(NAU7802_CALMOD_OFFSET)) {
Serial.println("Failed to calibrate system offset, retrying!");
delay(1000);
}
Serial.println("Calibrated system offset");
}
void loop() {
while (! nau.available()) {
delay(1);
}
int32_t val = nau.read();
Serial.print("Read "); Serial.println(val);
}
Attach a strain gauge with four wires to the four terminal inputs on the NAU7802. Upload the sketch to your board and open up the Serial Monitor (Tools -> Serial Monitor) at 115200 baud. You should see the values from the ADC being printed out. You'll see the value increase or decrease depending on the amount of force you are applying to the strain gauge.
Text editor powered by tinymce.
