Wiring

Connecting the MCP9600 to your Feather or Arduino is easy:

  • If you are running a 5V Arduino (Uno, etc.), connect Arduino 5V to MCP9601 VIN (red wire). If you are running a Feather (3.3V), connect Feather 3V to MCP9601 VIN.
  • Connect Feather or Arduino GND to MCP9601 GND (black wire)
  • Connect Feather or Arduino SCL to MCP9601 SCL (yellow wire)
  • Connect Feather or Arduino SDA to MCP9601 SDA (blue wire)
  • Connect thermocouple + to MCP9601 screw terminal +
  • Connect thermocouple - to MCP9601 screw terminal -

The final results should resemble the illustration above, showing an Adafruit Metro development board.

The MCP9601 may return a temperature for the hot junction even if there is no thermocouple connected. There will not be an error!

Library Installation

The MCP9601 uses the MCP9600 library.

You can install the Adafruit MCP9600 Library for Arduino using the Library Manager in the Arduino IDE:

Click the Manage Libraries ... menu item, search for Adafruit MCP9600, and select the Adafruit MCP9600 library:

Also get the Adafruit BusIO library

Load Example

Open up File -> Examples -> Adafruit MCP9600 -> mcp9601_test and upload to your Arduino wired up to the sensor.

Upload the sketch to your board and open up the Serial Monitor (Tools->Serial Monitor). You should see the the values for hot junction, cold junction and ADC.

Example Code

The following example code is part of the standard library, but illustrates how you can retrieve sensor data from the MCP9601 for the hot junction, cold junction and ADC values:

#include "Adafruit_MCP9601.h"

#define I2C_ADDRESS (0x67)

Adafruit_MCP9601 mcp;

void setup()
{
    Serial.begin(115200);
    while (!Serial) {
      delay(10);
    }
    Serial.println("Adafruit MCP9601 test");

    /* Initialise the driver with I2C_ADDRESS and the default I2C bus. */
    if (! mcp.begin(I2C_ADDRESS)) {
        Serial.println("Sensor not found. Check wiring!");
        while (1);
    }

  Serial.println("Found MCP9601!");

  mcp.setADCresolution(MCP9600_ADCRESOLUTION_18);
  Serial.print("ADC resolution set to ");
  switch (mcp.getADCresolution()) {
    case MCP9600_ADCRESOLUTION_18:   Serial.print("18"); break;
    case MCP9600_ADCRESOLUTION_16:   Serial.print("16"); break;
    case MCP9600_ADCRESOLUTION_14:   Serial.print("14"); break;
    case MCP9600_ADCRESOLUTION_12:   Serial.print("12"); break;
  }
  Serial.println(" bits");

  mcp.setThermocoupleType(MCP9600_TYPE_K);
  Serial.print("Thermocouple type set to ");
  switch (mcp.getThermocoupleType()) {
    case MCP9600_TYPE_K:  Serial.print("K"); break;
    case MCP9600_TYPE_J:  Serial.print("J"); break;
    case MCP9600_TYPE_T:  Serial.print("T"); break;
    case MCP9600_TYPE_N:  Serial.print("N"); break;
    case MCP9600_TYPE_S:  Serial.print("S"); break;
    case MCP9600_TYPE_E:  Serial.print("E"); break;
    case MCP9600_TYPE_B:  Serial.print("B"); break;
    case MCP9600_TYPE_R:  Serial.print("R"); break;
  }
  Serial.println(" type");

  mcp.setFilterCoefficient(3);
  Serial.print("Filter coefficient value set to: ");
  Serial.println(mcp.getFilterCoefficient());

  mcp.setAlertTemperature(1, 30);
  Serial.print("Alert #1 temperature set to ");
  Serial.println(mcp.getAlertTemperature(1));
  mcp.configureAlert(1, true, true);  // alert 1 enabled, rising temp

  mcp.enable(true);

  Serial.println(F("------------------------------"));
}

void loop()
{
  uint8_t status = mcp.getStatus();
  Serial.print("MCP Status: 0x"); 
  Serial.print(status, HEX);  
  Serial.print(": ");
  if (status & MCP9601_STATUS_OPENCIRCUIT) { 
    Serial.println("Thermocouple open!"); 
    return; // don't continue, since there's no thermocouple
  }
  if (status & MCP9601_STATUS_SHORTCIRCUIT) { 
    Serial.println("Thermocouple shorted to ground!"); 
    return; // don't continue, since the sensor is not working
  }
  if (status & MCP960X_STATUS_ALERT1) { Serial.print("Alert 1, "); }
  if (status & MCP960X_STATUS_ALERT2) { Serial.print("Alert 2, "); }
  if (status & MCP960X_STATUS_ALERT3) { Serial.print("Alert 3, "); }
  if (status & MCP960X_STATUS_ALERT4) { Serial.print("Alert 4, "); }
  Serial.println();
  
  Serial.print("Hot Junction: "); Serial.println(mcp.readThermocouple());
  Serial.print("Cold Junction: "); Serial.println(mcp.readAmbient());
  Serial.print("ADC: "); Serial.print(mcp.readADC() * 2); Serial.println(" uV");





  delay(1000);
}

You should get something resembling the following output when you open the Serial Monitor at 115200 baud:

This guide was first published on Aug 18, 2021. It was last updated on 2021-08-18 16:27:22 -0400.

This page (Arduino) was last updated on May 24, 2022.

Text editor powered by tinymce.