1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

// Connect LED positive to pins 9, 10, 11 with common ground.

#define MIC_PIN   A0      // connected to the out pin on the mic 
#define DC_OFFSET 3.3     // mic is plugged into 3.3v 

const byte HI_CUT = 255;  // upper brightness limit
const byte LO_CUT = 40;   // lower iimit turns LEDs off

// sample window width in mS (50 mS = 20Hz)
const int sampleWindow = 50;
unsigned int sample;

int LED_CENTER = 11;  // LED at center of the mouth
int LED_MIDDLE = 10;  // LEDs between the center and outside
int LED_OUTSDE = 9;   // LEDs on the outside of the mouth

void setup() {                
  // Serial.begin(9600);  // remove comment for debugging

  pinMode( LED_CENTER, OUTPUT );
  pinMode( LED_MIDDLE, OUTPUT );  
  pinMode( LED_OUTSDE, OUTPUT );  
}

void loop() {
  unsigned long startMillis= millis();  // start of sample window
  unsigned int peakToPeak = 0;          // peak-to-peak level
  unsigned int signalMax = 0;
  unsigned int signalMin = 1024;
  double lvl = 0;

  // collect data for 50 mS within a reasonable range
  while (millis() - startMillis < sampleWindow) {
    sample = analogRead(MIC_PIN);

    if (sample < 1024) {
      if (sample > signalMax) {
        signalMax = sample;
      } 
      else if (sample < signalMin) {
        signalMin = sample;
      }
    }
  }

  lvl = signalMax - signalMin;              // max - min = peak-peak amplitude
  lvl = ( lvl * DC_OFFSET );                // reduce operational range
  lvl = ( lvl < LO_CUT ? 0 : lvl );         // low cut filter for noise
  lvl = ( lvl > HI_CUT ? HI_CUT : lvl );    // high cut filter for clipping

  analogWrite( LED_CENTER, lvl );           // 100% brightness
  analogWrite( LED_MIDDLE, lvl * .8 );      // 80% brightness of center
  analogWrite( LED_OUTSDE, lvl * .3 );      // 30% brightness of center

  // Serial.println(lvl);  // remove comment for debugging
}